Pasted

REM -- A windows batch script used to disabled Windows Script Host on Windows registry.
REM -- Feel free to use & distribute.
REM -- Usage:
REM     Save this script as whatever_name.bat and run as administrator.
 
@echo off
 
set add_hk=SOFTWARE\Microsoft\Windows Script Host\Settings
 
reg query "HKLM\%add_hk%" /v Enabled > nul 2> nul
 
if %errorlevel% equ 0 (
    echo [+] Windows Script Host already disabled at HKLM. Skipped.
) else (
    reg add "HKLM\%add_hk%" /v Enabled /t REG_DWORD /d 0 > nul 2> nul
    if ERRORLEVEL 1 (
        echo [-] ERROR: Access denied. Check your permission.
    ) else (
        echo [+] WSH successfully disabled at HKLM.
    )
)
 
reg query "HKCU\%add_hk%" /v Enabled > nul 2> nul
 
if %errorlevel% equ 0 (
    echo [+] Windows Script Host already disabled HKCU. Skipped.
) else (
    reg add "HKCU\%add_hk%" /v Enabled /t REG_DWORD /d 0 > nul 2> nul
    if ERRORLEVEL 1 (
        echo [-] ERROR: Access denied. Check your permission.
    ) else (
        echo [+] WSH successfully disabled at HKCU.
    )
)
echo [+] FINISHED!