# Idlerpg Script (Auto Play)
# From SReject on Undernet!
# INSTRUCTIONS AT: http://idlerpg.org/forum/viewtopic.php?id=15
# WITH DOWNLOAD LINKS
#########################
on *:START:{ unset %mRPG:* | .mRPGReset }
on *:EXIT: .mRPGOff
on *:UNLOAD:.mRPGOff
on *:ACTIVE:*:if ($mRPG:Bot($mRPG:Char) == $active) .timermRPG-EbCheck -m 1 250 MRPG:EbCheck
on *:SIGNAL:MRPG_UPDATE: set %mRPG:Updated $ctime
on *:DIALOG:mRPG:*:*:{
if ($devent == init) {
if (!$line(@mRPG-Players,0)) mRPGUpdate
if (!$line(@mRPG-Players,0)) dialog -x $dname
else {
filter -wk @mRPG-Players mRPG:Load *
did -c $dname 44 $iif($didwm(mRPG,44,%mRPG:Stats),$v1,1)
mRPG:Stats
}
unset %mRPG:Stats
}
elseif ($devent == close) {
unset %mRPG:Stats
.timermRPG-Stats off
}
}
alias mRPGPlay {
if ($status != connected) echo -a 04/mRPGPlay: You must be connected to a server to use /mRPGPlay
elseif ($0 < 3) echo -a 04/mRPGPlay: Too few parameters specified please use: /mRPGPlay 12character password gamechan
elseif ($0 > 3) echo -a 04/mRPGPlay: Too many parameters specified, please use: /mRPGPlay 12character password gamechan
elseif (#* !iswm $3) echo -a 04/mRPGPlay: Invalid game channel specified!
elseif ($mRPG:Char) echo -a 04/mRPGPlay: You are already playing a character from this connection: $gettok($v1,1,32)
elseif ($mRPG:Played($1)) echo -a 04/mRPGPlay: You are already playing $1 from a diffarent connection, please use /mRPGStop from that connection then try again from this connection
else {
mRPGUpdate
if ($fline(@mRPG-Players,/^\Q $+ $replacecs($1,\E,\E\\E\Q) $+ \E\x01/i,1,2).text) {
echo -a 12/mRPGPlay: Now playing $gettok($v1,1,1) from this connection.
mRPG:Char $gettok($v1,1,1) $2-3
mRPG
}
else echo -a 04/mRPGPlay: I'm sorry, but $1 was not found in the players list.
}
}
alias mRPGList {
if ($var(%mRPG:Play:*,0)) {
var %x = 1
while ($var(%mRPG:Play:*,%x)) {
var %cid = $gettok($v1,3,$asc(:))
tokenize 32 $($v1,2)
echo -a 12/mRPGList: Playing $1 on $+($scid(%cid).network,12[,ConID: %cid,12])
inc %x
}
}
else echo -a 04/mRPGList: You are not currently playing any characters.
}
alias mRPGStats {
if ($0 > 1) echo -a 04/mRPGStats: Too many parameters specified. Please use: 12/mRPGStats [charname]
elseif ($dialog(mRPG)) {
if ($1 && $didwm(mRPG,44,$1)) { did -c mRPG 44 $v1 }
dialog -v mRPG
}
else {
if ($1) set -e %mRPG:Stats $1
dialog -m mRPG mRPGStats
}
}
alias mRPGStop {
if ($0) echo -a 04/mRPGStop: Too many parameters were specified, please use: 12/mRPGStop
elseif ($mRPG:Char) {
unset $+(%,mRPG:Play:,$cid)
echo -a 12/mRPGStop: Play script stopped for $gettok($v1,1,32)
}
else echo -a 04/mRPGStop: You are not currently playing a character from this connect.
}
alias mRPGReset {
if (!$0) {
.timermRPG-* off
close -@ @mRPG-*
if ($isfile($mircdirmRPG BestBet.txt)) .remove $qt($mircdirmRPG BestBet.txt)
if ($com(mRPG)) .comclose $v1
if ($isfile($mircdirmRPG Players.txt)) .remove $qt($mircdirmRPG players.txt)
if ($isfile($mircdirmRPG Players.vbs)) .remove $qt($mircdirmRPG Players.vbs)
if ($show) echo -a 12/mRPGReset: The script as been reset.
mRPGUpdate
}
else echo -a 04/mRPGReset: Too many parameters were specified, please use: 12/mRPGReset
}
alias mRPGOff {
if (!$0) {
.timermRPG-* off
close -@ @mRPG-*
unset %mRPG:*
if ($com(mRPG)) .comclose $v1
if ($dialog(mRPG)) dialog -x mRPG
if ($isfile($mircdirmRPG Players.txt)) .remove $qt($mircdirmRPG players.txt)
if ($isfile($mircdirmRPG Players.vbs)) .remove $qt($mircdirmRPG Players.vbs)
if ($isfile($mircdirmRPG BestBet.txt)) .remove $qt($mircdirmRPG BestBet.txt)
if ($show) echo -a 04/mRPGOff: All playing of MultiRPG has been stoppped.
}
else echo -a 04/mRPGOff: Too many parameters were specified, please use: 12/mRPGOff
}
alias mRPG:Read {
if (mRPG-Throttle:?* !iswm $1) return
var %w @ $+ $1
scid $gettok($1,2,58)
if ($status != connected || !$line(%w,0) || $mRPG:Bot($gettok($mRPG:Char,3,32)) == $null) { close -@ %w }
else {
msg $v1 $line(%w,1)
dline %w 1
$+(.timer,$1) -oi 1 6 mRPG:Read $1
}
}
alias MRPG:EbCheck {
if ($mRPG:Bot($gettok($mRPG:Char,3,32)) == $active) && ($editbox($active)) && ($timer(mRPG-Throttle: $+ $cid)) {
$+(.timer,$v1) -oi 1 30 mRPG:Read $v1
.timermRPG-ebcheck -m 1 250 MRPG:EbCheck
}
}
alias mRPG:Stats {
if (!$dialog(mRPG)) unset %mRPG:Stats
else {
if (!%mRPG:Updated) set -e %mRPG:Updated $ctime
tokenize 1 $fline(@mRPG-Players,$did(mRPG,44,1).seltext $+ $chr(1) $+ *,1).text
did -ra mRPG 45 $4
did -ra mRPG 46 $iif($22 == e,Evil[Undead],$iif($22 == g,Good[Priest],Neutral[Human]))
did -ra mRPG 47 $iif($4 < 10,N/A,$26 $+ /5)
did -ra mRPG 48 $iif($4 < 30,N/A,$27 $+ /5)
did -ra mRPG 49 $iif($5,Yes,No)
if ($5) {
did -ra mRPG 50 $iif($calc($6 - ($ctime - %mRPG:Updated)) < 1,Any Moment,$mRPG:Dur($v1))
did -ra mRPG 51 $iif($4 < 10,N/A,$iif($calc($7 - $ctime) < 0,Now,$mRPG:Dur($v1)))
did -ra mRPG 52 $iif($4 < 35,N/A,$iif($calc($8 - $ctime) < 0,Now,$mRPG:Dur($v1)))
did -ra mRPG 53 $iif($4 < 40,N/A,$iif($calc($9 - $ctime) < 0,Now,$mRPG:Dur($v1)))
}
else { did -ra mRPG 50,51,52,53 N/A while offline }
did -ra mRPG 54 $iif(!$31,N/A,$+($ord($32),[+,$calc(2+ $32),%,]))
did -ra mRPG 55 $iif(!$28,N/A,$+($ord($29),[+,$calc(2+ $29),%,]))
did -ra mRPG 56 $10
did -ra mRPG 57 $iif($22 == e,0.9,$iif($22 == n,1.0,1.1))
did -ra mRPG 58 $30
did -ra mRPG 59 $floor($calc($10 * $iif($22 == e,0.9,$iif($22 == n,1.0,1.1)) * $30))
did -ra mRPG 60 $12
did -ra mRPG 61 $13
did -ra mRPG 62 $14
did -ra mRPG 63 $15
did -ra mRPG 64 $16
did -ra mRPG 65 $17
did -ra mRPG 66 $18
did -ra mRPG 67 $19
did -ra mRPG 68 $20
did -ra mRPG 69 $21
did -ra mRPG 70 $34
did -ra mRPG 71 $35
did -ra mRPG 72 $36
did -ra mRPG 73 $24
did -ra mRPG 74 $25
did -ra mRPG 499 Updated $mRPG:Dur($calc($ctime - %mRPG:Updated)) ago.
.timermRPG-Stats -moi 1 250 mRPG:Stats
}
}
alias mRPGUpdate {
if ($com(mRPG)) return
if ($isfile($mircdirmRPG Players.txt)) .remove $qt($mircdirmRPG Players.txt)
if ($isfile($mircdirmRPG Players.vbs)) .remove $qt($mircdirmRPG Players.vbs)
if ($isfile($mircdirmRPG Bestbet.txt)) .remove $qt($mircdirmRPG Bestbet.txt)
var %f = write $qt($mircdirmRPG Players.vbs)
%f On Error Resume Next
%f if (err.number <> 0) then err.clear
%f set C = CreateObject("msxml2.xmlhttp.6.0")
%f if (err.number <> 0) then
%f err.clear
%f set C = CreateObject("msxml2.xmlhttp.4.0")
%f if (err.number <> 0) then
%f err.clear
%f set C = CreateObject("msxml2.xmlhttp.3.0")
%f if (err.number <> 0) then
%f err.clear
%f set C = CreateObject("msxml2.xmlhttp.2.6")
%f if (err.number <> 0) then
%f err.clear
%f wscript.quit
%f end if
%f end if
%f end if
%f end if
%f C.open "GET", "http://www.idlerpg.org/rawplayers3.php?nocache="&timer, false
%f C.send
%f if (err.number <> 0) then
%f if (Hex(err.Number) <> "800C0005") then
%f err.clear
%f wscript.quit
%f else
%f err.clear
%f C.open "GET", "http://www.multirpg.org/rawplayers3.php?nocache="&timer, false
%f C.send
%f if (err.Number <> 0) then
%f err.clear
%f wscript.Quit
%f end if
%f end if
%f end if
%f set F = CreateObject("Scripting.FileSystemObject").CreateTextFile(" $+ $mircdirmRPG Players.txt")
%f if (err.number <> 0) then
%f err.clear
%f WScript.Quit
%f end if
%f BetChars = ""
%f set R = New RegExp
%f R.IgnoreCase = true
%f R.Global = True
%f R.Multiline = True
%f R.Pattern = "^(rank \d+ char ([^\x20]+) network ([^\x20]+) userhost ([^\x20]+) level (\d+) created \d+ lastlogin \d+ online (0|1) sex (?:male|female|not_set) class \{[^\}]+\} team \d+ ttl (\d+) regentm (\d+) challengetm (\d+) slaytm (\d+) idled \d+ x_pos \d+ y_pos \d+ sum (\d+) amulet ([a-z]?\d+[a-z]?) charm ([a-z]?\d+[a-z]?) helm ([a-z]?\d+[a-z]?) boots ([a-z]?\d+[a-z]?) gloves ([a-z]?\d+[a-z]?) ring ([a-z]?\d+[a-z]?) leggings ([a-z]?\d+[a-z]?) shield ([a-z]?\d+[a-z]?) tunic ([a-z]?\d+[a-z]?) weapon ([a-z]?\d+[a-z]?) align (n|e|g) alignchanged [01] powerpots (\d+) luckpots (\d+) fights ([0-5]) bets ([0-5]) bwon \d+ blost \d+ badd \d+ bminus \d+ hero (0|1) hlevel (\d+) engineer (0|1) englevel (\d+) gold (-?\d+) bank (\d+))"
%f for each L in R.Execute(C.ResponseText)
%f Aln = L.SubMatches(21)
%f Amd = 1.0
%f if (Aln = "e") then Amd = "0.9"
%f if (Aln = "g") then Amd = "1.1"
%f Hro = L.SubMatches(26)
%f HLv = L.SubMatches(27)
%f Hmd = 1.0
%f if (Hro = "1") then Hmd = 1.02 + .01 * CInt(Hlv)
%f Eng = L.SubMatches(28)
%f ELv = L.SubMatches(29)
%f Emd = 1.0
%f if (Eng = "1") then Emd = 1.02 + .01 * CInt(Elv)
%f MSm = L.SubMatches(10) * Amd * Hmd
%f F.WriteLine(Join(Array(L.SubMatches(1),L.SubMatches(2),L.SubMatches(3),L.SubMatches(4),L.SubMatches(5),L.SubMatches(6),L.SubMatches(7),L.SUbMatches(8),L.SubMatches(9),L.SubMatches(10),MSm,L.SubMatches(11),L.SubMatches(12),L.SubMatches(13),L.SubMatches(14),L.SubMatches(15),L.SubMatches(16),L.SubMatches(17),L.SubMatches(18) ,L.SUbMatches(19),L.SubMatches(20) ,Aln,AMd,L.SubMatches(22),L.SubMatches(23),L.SubMatches(24),L.SubMatches(25),Hro,HLv,HMd,Eng,Elv,EMd,L.SubMatches(30),L.SubMatches(31),CDbl(L.SubMatches(30)) + CDbl(L.SUbMatches(31))),""))
%f if (L.SubMatches(5) = 1 and L.SubMatches(4) > 29) then
%f if (BetChars <> "") then BetChars = BetChars & vbcrlf
%f Betchars = Betchars & Cint(L.SubMatches(4)) * 10000000 + CInt(L.SubMatches(10)) & " " & L.SubMatches(1)
%f end if
%f next
%f F.Close
%f arryChars = Split(BetChars,vbcrlf)
%f if (UBound(ArryChars,1) < 0) then wScript.Quit
%f for a = 0 to ubound(arryChars,1)
%f for b = a + 1 to ubound(arryChars,1)
%f cchr = Split(arryChars(a)," ")
%f nchr = Split(arryChars(b)," ")
%f if (cdbl(cchr(0)) < cdbl(nchr(0))) then
%f temp = arryChars(b)
%f arryChars(b) = arrychars(a)
%f arryChars(a) = temp
%f end if
%f next
%f next
%f cChr = Split(ArryChars(0)," ")
%f BetChars = cChr(1) & " " & CInt(cChr(0) / 10000000) & " " & cChr(0) mod 10000000 & vbcrlf
%f for a = 1 to uBound(ArryChars,1) -1
%f pChr = Split(ArryChars(a -1), " ")
%f cChr = Split(ArryChars(a)," ")
%f cLvl = CInt(cChr(0) / 10000000)
%f nChr = Split(ArryChars(a +1), " ")
%f if (cInt(pChr(0) / 10000000) <> cLvl or cLvl <> CInt(nChr(0) / 10000000)) then
%f BetChars = BetChars & cChr(1) & " " & cLvl & " " & cChr(0) mod 10000000 & vbcrlf
%f end if
%f next
%f cChr = Split(ArryChars(Ubound(ArryChars,1))," ")
%f arrychars = Split(BetChars & cChr(1) & " " & CInt(cChr(0) / 10000000) & " " & cChr(0) mod 10000000,vbcrlf)
%f odds = 0.0
%f bestbet = ""
%f for a = UBound(ArryChars) to 1 step -1
%f aChr = Split(ArryChars(a)," ")
%f for b = a -1 to 0 step -1
%f bChr = Split(ArryChars(b)," ")
%f if (aChr(1) <= bChr(1)) and (odds < aChr(2) / bChr(2)) then
%f bestbet = aChr(0) & " " & bChr(0)
%f odds = aChr(2) / bChr(2)
%f end if
%f if (aChr(1) = bChr(1)) and (odds < bChr(2) / aChr(2)) then
%f bestbet = bChr(0) & " " & aChr(0)
%f odds = bChr(2) / aChr(2)
%f end if
%f next
%f next
%f if (odds <> 0.0) then
%f set a = CreateObject("Scripting.FileSystemObject").CreateTextFile(" $+ $Mircdirmrpg bestbet.txt")
%f a.write(bestbet)
%f a.close
%f end if
.comopen mRPG WScript.Shell
if ($comerr) goto error
if (!$com(mRPG,Run,1,bstr," $+ $mircdirmRPG Players.vbs",uint,0,bool,true)) goto error
if ($lines($mircdirmRPG Players.txt) == 0) goto error
unset %mRPG:BestBet
if ($isfile($mircdirmRPG BestBet.txt)) set %mRPG:BestBet $read($mircdirmRPG Bestbet.txt,n,1)
window -hl @mRPG-Players
loadbuf -r @mRPG-Players $qt($mircdirmRPG Players.txt)
scon -at1 mRPG
.signal -n MRPG_UPDATE
:error
if ($error) reseterror
unset %mRPG:BestBet
if ($com(mRPG)) .comclose mRPG
if ($com(mRPG2)) .comclose mRPG2
if ($isfile($mircdirmRPG BestBet.txt)) .remove $qt($mircdirmRPG BestBet.txt)
if ($isfile($mircdirmRPG Players.txt)) .remove $qt($mircdirmRPG Players.txt)
if ($isfile($mircdirmRPG Players.vbs)) .remove $qt($mircdirmRPG Players.vbs)
.timermRPG-Update -oi 0 90 mRPGUpdate
}
alias -l mRPG {
if (!$line(@mRPG-Throttle: $+ $cid,0)) && ($mRPG:GetChar) {
var %pwd = $gettok($v1,1,32), %gcn = $gettok($v1,2,32), %bot = $mRPG:Bot(%gcn), %mSum, %att, %chl, %sly, %fht
tokenize 1 $gettok($v1,3-,32)
if ($me !ison %gcn) join $v2
elseif (%bot) {
if ($5 != 1) mRPG:Msg Login $1 %pwd
else {
%mSum = $iif($22 != g,$calc($10 * 1.1 * $30),$23)
%att = $iif($4 > 9 && $calc($7 - $ctime) < -5 && $mRPG:Creeps($4),$v1)
%chl = $iif($4 > 34 && $calc($8 - $ctime) < -5,$true)
%sly = $iif($4 > 39 && $calc($9 - $ctime) < -5 && $mRPG:Monsters($10),$v1)
%fht = $iif($4 > 9 && $26 < 5 && $mRPG:Fight($1,$4),$v1)
if (%att || %chl || %sly || %fht) {
if ($22 != g) mRPG:Msg align priest
if (%att) mRPG:Msg attack $v1
if (%chl) mRPG:Msg challenge
if (%sly) mRPG:Msg slay $v1
if (%fht) {
var %x = $calc(5 - $25)
while (%x) {
mRPG:Msg Fight %fht
dec %x
}
}
if ($22 != g) mRPG:Msg align $iif($22 == e,undead,human)
}
elseif ($4 > 29) && (5 > $27) && ($36 > 139) && (?* ?* iswm %mRPG:BestBet) {
if ($34 < 140) mRPG:Msg bank withdraw $calc(140 - $34)
mRPG:Msg bet $gettok(%mRPG:BestBet,1-2,32) 100
}
elseif ($34 > 40) {
mRPG:Msg bank deposit $calc($34 - 40)
}
elseif ($34 < 40) && ($36 >= 40) {
mRPG:Msg bank withdraw $calc(40 - $34)
}
}
}
}
}
alias -l mRPG:Char if ($isid) return $($+(%,mRPG:Play:,$cid),2) | set $+(%,mRPG:Play:,$cid) $1-
alias -l mRPG:Bot return $fline($1,/^(idle|multi)rpg0*$/i,$fline($1,/^(idle|multi)rpg0*$/i,0,3),3).text
alias -l mRPG:Played var %x = 1 | while ($var(%mRPG:Play:,%x).value) { if ($gettok($v1,1,32) == $1) return $true | inc %x }
alias -l mRPG:GetChar tokenize 32 $mRPG:Char | var %n = /^\Q $+ $replacecs($1,\E,\E\\E\Q) $+ \E\x01/i | if ($fline(@mRPG-Players,%n,$fline(@mRPG-Players,%n,0,2),2).text) return $2-3 $v1
alias -l mRPG:Load did -a mRPG 44 $gettok($1-,1,1)
alias -l mRPG:Dur { return $iif($floor($calc($1 / 86400)) > 0,$iif($v1 == 1,1day,$v1 $+ days)) $duration($calc($1 % 86400),3) }
alias -l mRPG:Msg {
var %win = @mRPG-Throttle: $+ $cid, %t = $mid(%win,2-)
if ($status != connected) close -@ %win
else {
if (!$window(%win)) window -lhn %win
aline %win $1-
if (!$timer(%t)) mRPG:Read %t
}
}
alias -l mRPG:Fight {
if (!$line(@mRPG-Players,0) || !$1 || !$2) { return }
window -nh @mRPG-Fight
filter -wwgc @mRPG-Players @mRPG-Fight ^[^]+[^]+[^]+[^]+1
var %x = 1, %Chr, %Sum, %ln
while ($line(@mRPG-Fight,%x)) {
%ln = $v1
if ($gettok(%ln,4,1) < $2) break
elseif ($1 != $gettok(%ln,1,1)) && (!%sum || $gettok(%ln,11,1) < %Sum) { var %Chr = $gettok(%ln,1,1), %Sum = $gettok(%ln,11,1) }
inc %x
}
close -@ @mRPG-Fight
return %Chr
}
dialog mRPGStats {
title "mRPG - Stats"
size -1 -1 181 247
option dbu
tab "Stats", 1, 1 1 180 233
text "Character:", 2, 5 18 27 8, tab 1
text "Level:", 3, 5 30 27 8, tab 1
text "Alignment:", 4, 5 41 27 8, tab 1
text "Fights:", 5, 5 52 27 8, tab 1
text "Bets:", 6, 5 63 27 8, tab 1
text "Online:", 7, 101 19 19 8, tab 1
text "TTL:", 8, 101 30 12 8, tab 1
text "TTA:", 9, 101 41 12 8, tab 1
text "TTC:", 10, 101 52 12 8, tab 1
text "TTS:", 11, 101 63 12 8, tab 1
text "Engineer:", 12, 5 85 27 8, tab 1
text "Hero:", 13, 101 85 13 8, tab 1
text "Base", 14, 31 103 25 7, tab 1 center
text "Align", 15, 75 103 18 7, tab 1 center
text "Hero", 16, 111 103 18 7, tab 1 center
text "Total", 17, 147 103 28 7, tab 1 center
text "Sum:", 18, 5 112 25 8, tab 1
text "X", 19, 60 112 11 8, tab 1 center
text "X", 20, 97 112 11 8, tab 1 center
text "=", 21, 133 111 11 8, tab 1 center
text "Amulet:", 22, 10 127 25 8, tab 1
text "Charm:", 23, 10 137 25 8, tab 1
text "Helm:", 24, 10 147 25 8, tab 1
text "Boots:", 25, 10 157 25 8, tab 1
text "Gloves:", 26, 10 167 25 8, tab 1
text "Ring:", 27, 93 127 25 8, tab 1
text "Leggings:", 28, 93 137 25 8, tab 1
text "Shield:", 29, 93 147 25 8, tab 1
text "Tunic:", 30, 93 157 25 8, tab 1
text "Weapon:", 31, 93 167 25 8, tab 1
text "Carried", 32, 43 185 25 7, tab 1 center
text "Banked", 33, 87 185 25 7, tab 1 center
text "Total", 34, 128 185 25 7, tab 1 center
text "Gold:", 35, 23 194 16 8, tab 1
text "+", 36, 72 194 11 8, tab 1 center
text "=", 37, 115 194 11 8, tab 1 center
text "Power Potions:", 38, 5 218 40 8, tab 1
text "Luck Potions:", 39, 109 218 35 8, tab 1
box "", 40, 5 73 171 5, tab 1
box "", 41, 5 96 171 5, tab 1
box "", 42, 5 178 171 5, tab 1
box "", 43, 5 205 171 5, tab 1
combo 44, 32 17 60 200, tab 1 sort size drop
edit "", 45, 32 28 60 10, tab 1 read right
edit "", 46, 32 39 60 10, tab 1 read right
edit "", 47, 32 50 60 10, tab 1 read right
edit "", 48, 32 61 60 10, tab 1 read right
edit "", 49, 125 17 50 10, tab 1 read right
edit "", 50, 115 28 60 10, tab 1 read right
edit "", 51, 115 39 60 10, tab 1 read right
edit "", 52, 115 50 60 10, tab 1 read right
edit "", 53, 115 61 60 10, tab 1 read right
edit "", 54, 35 83 60 10, tab 1 read right
edit "", 55, 115 83 60 10, tab 1 read right
edit "", 56, 31 110 25 10, tab 1 read center
edit "", 57, 75 110 18 10, tab 1 read center
edit "", 58, 111 110 18 10, tab 1 read center
edit "", 59, 147 110 28 10, tab 1 read center
edit "", 60, 37 125 50 10, tab 1 read right
edit "", 61, 37 135 50 10, tab 1 read right
edit "", 62, 37 145 50 10, tab 1 read right
edit "", 63, 37 155 50 10, tab 1 read right
edit "", 64, 37 165 50 10, tab 1 read right
edit "", 65, 120 125 50 10, tab 1 read right
edit "", 66, 120 135 50 10, tab 1 read right
edit "", 67, 120 145 50 10, tab 1 read right
edit "", 68, 120 155 50 10, tab 1 read right
edit "", 69, 120 165 50 10, tab 1 read right
edit "Carried", 70, 43 192 25 10, tab 1 read center
edit "Banked", 71, 87 192 25 10, tab 1 read center
edit "GTOT", 72, 128 192 25 10, tab 1 read center
edit "Power", 73, 46 216 30 10, tab 1 read center
edit "Luck", 74, 145 216 30 10, tab 1 read center
text "", 499, 1 237 100 10
button "Close", 500, 144 235 37 12, ok cancel
}
alias -l mRPG:Creeps {
if (!$1 || $1 < 10) { return }
if ($1 == 10) { return Bush }
if ($1 < 16) { return Locust }
if ($1 < 21) { return Spider }
if ($1 < 31) { return Goblin }
if ($1 < 41) { return Lich }
if ($1 < 51) { return Skeleton }
if ($1 < 61) { return Ghost }
if ($1 < 71) { return Shadow }
;if ($1 < 81) { return Troll }
;if ($1 < 91) { return Cyclop }
;if ($1 < 101) { return Mutant }
if ($1 < 111) { return Monkey }
if ($1 < 121) { return Phoenix }
if ($1 < 131) { return Minotaur }
if ($1 < 141) { return Beholder }
}
alias -l mRPG:Monsters {
if (6000 <= $1) { return Hippogriff }
if (5000 <= $1) { return Sphinx }
if (4500 <= $1) { return Dragon }
if (4000 <= $1) { return Vampire }
if (3500 <= $1) { return Mammoth }
if (3000 <= $1) { return Centaur }
return Medusa
}
Comments