Pasted

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; This mIRC script lets you search users by hostname mask and make them join your channel
; You have to prepare file named "ids.txt" with hostname ids of people you like to join your channel
; Each hostname record has to start as newline. Put this file to the following directory:
; (Your hard drive where mIRC is installed)/users/(Your User Name)/Application Data/mIRC
; For example it might be the following file: C:/users/root/Application Data/mIRC/ids.txt
; To get simple hostname record run "/who yournick" in IRC to see your own hostname record
; Next, add the following script lines to the mIRC - Tools - Script editor (Alt+R) - Remote section
; After you add them at the bottom, please run the script like following:
; /usearch #channel-to-search #channel-to-invite 
;                                                                written by Security XIII on 25.12.2014
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
; custom alias "/usearch #channel-to-search #channel-to-invite"
alias usearch {
  ; request names list
  names $$1
  ; global variable storing the name of the channel to search and channel to invite
  set -en %usearch $1
  set -en %invitech $2
}
 
; names reply
raw 353:*: { 
  ; reply is for the channel in question
  if ($3 == %usearch) {
    ; write names to file    
    ;  write $v1 $+ .txt $4-
    var %word = 1
    while (%word <= $numtok($4-,32)) {
      echo -a UserID: %word
      who $gettok($4-,%word,32)
      set %unick $gettok($4-,%word,32)
      set %uaddr $address(%unick,0)
      echo -a UserNick: %unick
      echo -a UserAddress: %uaddr
      while ($read(ids.txt, nw, %uaddr, $calc($readn + 1))) set %compare $v1
      if (%uaddr == %compare) { SAJOIN %unick %invitech } 
      else { echo -a user hostname not found in list }
      inc %word
    }
    ; halt default display
    haltdef
  }
}
 
; 'end of names' reply
raw 366:*: { 
  ; reply is for the channel in question
  if ($2 == %usearch) {
    unset %usearch
    haltdef
  }
}