###################################
# Note System Coded By xplorer    #
# lemery.sebastien@gmail.gom      #
#         #mircscripting          #
#        irc.undernet.org         #
###################################
ON *:TEXT:!addnote *:#:{ 
  if ($nick isop $chan || $istok(%noteadmin,$address($nick,2),32) || $istok(%superadmin,$address($nick,2),32)) {
    if ($($+(%,info,$2),2)) {
      msg $chan Information for $2 is already registered!
    }
    else {
      set $+(%,info,$2) $3- (Added By: $fulladdress On: $fulldate $+ )
      msg $chan Informations 9ADDED! 
    } 
  }
  else { 
    msg $chan $nick You need @ to !ADDNOTE
  } 
}
ON *:TEXT:!remnote *:#:{ 
  if ($nick isop $chan || $istok(%noteadmin,$address($nick,2),32) || $istok(%superadmin,$address($nick,2),32)) {
    if ($($+(%,info,$2),2)) {
      unset $+(%,info,$2)
      msg $chan Informations 4DELETED! 
    }
    else {
      msg $chan $nick Information for $2 does not exist!
    }
  }
  else { 
    msg $chan $nick You need @ to !REMNOTE 
  } 
}
ON *:TEXT:!note *:#:{
  if ($nick isop $chan || $istok(%noteadmin,$address($nick,2),32) || $istok(%superadmin,$address($nick,2),32)) { 
    if ($($+(%,info,$2),2)) { 
      msg $chan Info for $+($2,:) $ifmatch 
    } 
    else { 
      msg $chan * $+ $nick $+ * I have nothing in the database for $2 
    } 
  }
}
on *:TEXT:!notecount:#:{
  if ($nick isop $chan || $istok(%noteadmin,$address($nick,2),32) || $istok(%superadmin,$address($nick,2),32)) { 
    msg $chan $var(%info*,0) 
  }
}
on *:TEXT:!remallnote:#:{
  if ($istok(%noteadmin,$address($nick,2),32) || $istok(%superadmin,$address($nick,2),32)) {
    unset %info*
    msg $chan $nick all notes have been erased!
  }
  else {
    msg $chan $nick you cannot use this command!
  }
}
on *:TEXT:!addnoteadmin *:#:{
  if ($istok(%superadmin,$address($nick,2),32)) {
    if (!$istok(%noteadmin,$2,32)) {
      set %noteadmin $addtok(%noteadmin,$2,32)
      msg $chan $nick $2 has been added to Note Admins!
    }
    else {
      msg $chan $nick $2 is already added to Note Admins!
    }
  }
  else {
    msg $chan $nick you cannot use this command!
  }
}
on *:TEXT:!delnoteadmin:#:{
  if ($istok(%superadmin,$address($nick,2),32)) {
    if ($istok(%noteadmin,$2,32)) {
      set %noteadmin $deltok(%noteadmin,$2,32)
      msg $chan $nick $2 has been deleted from Note Admins!
    }
    else {
      msg $chan $nick $2 is not in Note Admins!
    }
  }
  else {
    msg $chan $nick you cannot use this command!
  }
}
on *:TEXT:!noteshow:#:{
  if ($nick isop $chan || $istok(%noteadmin,$address($nick,2),32) || $istok(%superadmin,$address($nick,2),32)) { 
    if ($var(%info*,0) > 0) {
      var %i = $var(%info*,0)
      var %j = 1
      while (%j <= %i) {
        set %allinfo $iif($(%allinfo),$(%allinfo) -,$null) $remove($var(%info*,%j),$(%info,0))
        inc %j
      }
      msg $chan Notes are added for %allinfo $+ .
      unset %allinfo
    }
    else {
      msg $chan $nick I have no notes added!
    }
  }
}
ON *:TEXT:!modnote *:#:{ 
  if ($nick isop $chan || $istok(%noteadmin,$address($nick,2),32) || $istok(%superadmin,$address($nick,2),32)) {
    if ($($+(%,info,$2),2)) {
      set $+(%,info,$2) $3- (Modified By: $fulladdress On: $fulldate $+ ) $chr(124) $($+(%,info,$2),2)
      msg $chan Informations 9MODIFIED! 
    } 
    else {
      msg $chan $nick Information for $2 does not exist, Use !addnot instead!
    }
  }
  else { 
    msg $chan $nick You need @ to !MODNOTE
  } 
}
on *:TEXT:!notehelp:#:{
  if ($nick isop $chan || $istok(%noteadmin,$address($nick,2),32) || $istok(%superadmin,$address($nick,2),32)) {
    notice $nick You NEED to be 4@(op) in the channel to use the note system.
    .timer -m 1 500 notice $nick Type 4!ADDNOTE <Username> Make Sure your adding the username 4*NOT4* The nickname
    .timer -m 1 1000 notice $nick Here is an example 
    .timer -m 1 1500 notice $nick !ADDNOTE 4Username 9(Added/Suspended/deleted/modified) user to level 7<level>
    .timer -m 1 2000 notice $nick Type 4!MODNOTE <Username> To Add a note.
    .timer -m 1 2500 notice $nick Type 4!REMNOTE <Username> To Delete.
    .timer -m 1 3000 notice $nick Type 4!NOTE <Username> To Check the infos. 
    .timer -m 1 3500 notice $nick Type 4!NOTESHOW To Show Usernames that have infos.
    .timer -m 1 4000 notice $nick Type 4!REMALLNOTE To Delete all notes.
    .timer -m 1 4500 notice $nick Type 4!NOTECOUNT To See the number of notes.
  }
}

on *:LOAD:{ 
  echo -a 4» »08 Note System Script Successfully Loaded.
  echo -a 4» »08 Copyright © 200915 http://xplorer.mircscripting.info
  echo -a 4» »08 Written by: 15 xplorer 08 Email: 15 xplorer@live.ca
}