@echo off
:: NO support :: Use at your own risk :: no warranty ::
::
:: choco_dl_install.bat
::   01/06/2017 :: By: JaCk 
::   03/05/2015 :: JaCk -- Removed prompt changes to cmd console; make jack's apps optional
::

:: Admin Check 
set "_console_elevated=" 
"%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system" 2>&1>nul && set /a "_console_elevated+=1"


if not defined _console_elevated (
	echo Set Admin = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo Admin.ShellExecute WScript.Arguments^(0^), "", "", "runas", 1 >> "%temp%\getadmin.vbs"
)


if defined _console_elevated (
	echo INFO: Admin Elevated Console [x]
	goto gotAdmin
) else (
	echo INFO: Admin Elevated Console [ ]
	if exist "%temp%\getadmin.vbs" (
		echo INFO: Starting Script in Admin Mode.
		call cscript "%temp%\getadmin.vbs" "%~s0"
	) else (
		echo ERROR: Please restart with admin privledges...
		timeout /t 30	
	)
)

goto :eof
:gotAdmin

:: Download and intall Chocolatey
@powershell -NoProfile -ExecutionPolicy Bypass -Command "iex ((New-Object System.Net.WebClient).DownloadString('https://chocolatey.org/install.ps1'))" && SET "PATH=%PATH%;%ALLUSERSPROFILE%\chocolatey\bin"

set "install_jack_apps=N"
set /p "install_jack_apps=Prompt: Install jacks applist? [y/N]:"
if /i "%install_jack_apps:~0,1%" neq "y" (
	refreshenv
	timeout /t 60
	goto :eof
)

:: Update to latest version
choco upgrade -y all

:: Install all apps 
choco install -y ^
ChocolateyGUI DotNet3.5 ^
GoogleChrome ^
7zip winrar ^
cccp spotify mpc-hc aimp vlc mediatab obs-studio audioshell ^
irfanview irfanviewplugins ^
python3 jre8 jdk8 ^
notepadplusplus openinsublimetext sublimetext3 sublimetext3.packagecontrol sublimetext3-contextmenu ^
VisualStudio2015Community npm bower nodejs nodejs.install npmtaskrunner nodejs.commandline flattenpackages io.js ^
qbittorrent utorrent ^
mumble curse-voice skype discord ^
poweriso universal-usb-installer linkshellextension hddguardian sysinternals windirstat shutup10

:: Special Downloader
choco install -y  --allowemptychecksumsecure --allowemptychecksum ^
steam battle.net ^
mipony

:: Install Non-Admin 
choco install -y ^
spotify

refreshenv
timeout /t 60