;This can be used to connect and auth to services safely. Read the whole script. 

on *:start:{ 
  server irc.undernet.org -i Mainnick Altnick ident full name here
  server -m irc.freenode.org -i Mainnick Altnick ident full name here
}

on *:connect:{ 
  .timer 1 10 join -n %aj. [ $+ [ $network ] ] 
  if ($network == undernet) { .msg x@channels.undernet.org login USERNAME PASSWORD }
}

on *:INVITE:#:{ if ($nick == X) { .join -n $chan } }

on *:NOTICE:*This nickname is registered*:*:{ 
  if ($nick == NickServ) && ($network == freenode) { .ns id YOURFREENODEPASSWORD } 
}

menu status {
  Autojoin on $network
  .List
  ..$submenu($channel_list($1))
  .Join list now:join -n %aj. [ $+ [ $network ] ]
}

menu channel {
  Autojoin on $network
  .Add $chan:set $+(%,aj,.,$network) $addtok($eval($+(%,aj,.,$network),2),$chan,44)
  .Remove $chan:set $+(%,aj,.,$network) $remtok($eval($+(%,aj,.,$network),2),$chan,44)
  .-
  .Join list now:join -n %aj. [ $+ [ $network ] ]
  .-
  .$submenu($channel_list($1))
}

alias channel_list {
  if ($istok(begin end,$1,32)) return -
  else return $gettok($($+(%,aj.,$network),2),$1,44) :noop
}