buildscript {
	repositories {
		jcenter()
		mavenCentral()
		maven { url "https://files.minecraftforge.net/maven" }
		mavenLocal()
	}
	dependencies {
		classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '3.+', changing: true
		classpath('com.gamebuster19901:LicenseChecker'){
			version {
				branch = "master"
			}
		}
	}
}
apply plugin: 'net.minecraftforge.gradle'
// Only edit below this line, the above code adds and enables the necessary things for Forge to be setup.
apply plugin: 'eclipse'
apply plugin: 'maven-publish'

version = "1.15.2-1.7.2.0"
group = "com.gamebuster19901" // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = "guncore"

sourceCompatibility = targetCompatibility = '1.8' // Need this here so eclipse task generates correctly.
compileJava {
	sourceCompatibility = targetCompatibility = '1.8'
}

minecraft {
	// The mappings can be changed at any time, and must be in the following format.
	// snapshot_YYYYMMDD   Snapshot are built nightly.
	// stable_#			Stables are built at the discretion of the MCP team.

	// Use non-default mappings at your own risk. they may not always work.
	// Simply re-run your setup task after changing the mappings to update your workspace.
	mappings channel: 'snapshot', version: '20200916-1.15.1'
	// makeObfSourceJar = false // an Srg named sources jar is made by default. uncomment this to disable.
	
	accessTransformer = file('src/main/resources/main/META-INF/accesstransformer.cfg')

	// Default run configurations.
	// These can be tweaked, removed, or duplicated as needed.
	runs {
		client {
			workingDirectory project.file('run')

			// Recommended logging data for a userdev environment
			property 'forge.logging.markers', 'SCAN,REGISTRIES,REGISTRYDUMP'

			// Recommended logging level for the console
			property 'forge.logging.console.level', 'debug'

			mods {
				guncore {
					source sourceSets.main
				}
			}
		}

		server {
			workingDirectory project.file('run')

			// Recommended logging data for a userdev environment
			property 'forge.logging.markers', 'SCAN,REGISTRIES,REGISTRYDUMP'

			// Recommended logging level for the console
			property 'forge.logging.console.level', 'debug'

			mods {
				guncore {
					source sourceSets.main
				}
			}
		}
	}
}

dependencies {
	// Specify the version of Minecraft to use, If this is any group other then 'net.minecraft' it is assumed
	// that the dep is a ForgeGradle 'patcher' dependency. And it's patches will be applied.
	// The userdev artifact is a special name and will get all sorts of transformations applied to it.
	minecraft 'net.minecraftforge:forge:1.15.2-31.2.41'

	// You may put jars on which you depend on in ./libs or you may define them like so..
	// compile "some.group:artifact:version:classifier"
	// compile "some.group:artifact:version"

	// Real examples
	// compile 'com.mod-buildcraft:buildcraft:6.0.8:dev'  // adds buildcraft to the dev env
	// compile 'com.googlecode.efficient-java-matrix-library:ejml:0.24' // adds ejml to the dev env

	// The 'provided' configuration is for optional dependencies that exist at compile-time but might not at runtime.
	// provided 'com.mod-buildcraft:buildcraft:6.0.8:dev'

	// These dependencies get remapped to your current MCP mappings
	// deobf 'com.mod-buildcraft:buildcraft:6.0.8:dev'

	// For more info...
	// http://www.gradle.org/docs/current/userguide/artifact_dependencies_tutorial.html
	// http://www.gradle.org/docs/current/userguide/dependency_management.html

}

// Example for how to get properties into the manifest for reading by the runtime..
jar {
	manifest {
		attributes([
			"Specification-Title": "guncore",
			"Specification-Vendor": "examplemodsareus",
			"Specification-Version": "1", // We are version 1 of ourselves
			"Implementation-Title": project.name,
			"Implementation-Version": "${version}",
			"Implementation-Vendor" :"examplemodsareus",
			"Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
		])
	}
}

task checkVersion() {
	def versionRegex = ~'(?i)version(?i-)\\s?=\\s?\\"[\\w.-]*\\"';
	
	def gradlef = project.buildscript.sourceFile.toString();
	def dir = new File(gradlef).getParent().toString();
	
	String allContainingFiles = 
		new File(dir + '/src/main/java/com/gamebuster19901/guncore/Main.java').text +
		new File(dir + '/src/main/resources/META-INF/mods.toml').text +
		new File(gradlef).text
		
	allContainingFiles = allContainingFiles.replaceAll(' ','')
		
	def matcher = allContainingFiles =~ versionRegex
	
	assert matcher.find();
	assert matcher.size() == 3;
	assert matcher[0].equalsIgnoreCase(matcher[1]) && matcher[1].equalsIgnoreCase(matcher[2])

	logger.info("Version verified: " + matcher[0])
}

task checkLicenses(type: JavaExec) {
	classpath += sourceSets.main.runtimeClasspath
	classpath += buildscript.configurations.classpath
	println main = "com.gamebuster19901.license.LicenseChecker"
	args = ['notBinary', 'silenceSkips', "classes:com.gamebuster19901.license.test.Test"]
}

build.dependsOn checkVersion
build.dependsOn checkLicenses
build.finalizedBy publish
jar.dependsOn checkLicenses

task applyLicenses(type: JavaExec) {
	classpath += sourceSets.main.runtimeClasspath
	classpath += buildscript.configurations.classpath
	println main = "com.gamebuster19901.license.LicenseChecker"
	args = ['notBinary', 'applyLicenses']
}

task editLicenses(type:JavaExec) {
	classpath += sourceSets.main.runtimeClasspath
	classpath += buildscript.configurations.classpath
	standardInput = System.in
	println main = "com.gamebuster19901.license.create.CreateChecker"
	args = ['notBinary', 'applyLicenses']
}

task stripLicenses(type:JavaExec){
	classpath += sourceSets.main.runtimeClasspath
	classpath += buildscript.configurations.classpath
	standardInput = System.in
	println main = "com.gamebuster19901.license.LicenseChecker"
	args = ['notBinary', 'stripLicenses']
}

// Example configuration to allow publishing using the maven-publish task
// we define a custom artifact that is sourced from the reobfJar output task
// and then declare that to be published
// Note you'll need to add a repository here
def reobfFile = file("$buildDir/reobfJar/output.jar")
def reobfArtifact = artifacts.add('default', reobfFile) {
	type 'jar'
	builtBy 'reobfJar'
}
publishing {
	publications {
		mavenJava(MavenPublication) {
			artifact reobfArtifact
		}
	}
	repositories {
		mavenLocal()
	}
}