#copy paste this code into your remotes (new file) and in mIRC type /noame or click the option in the menu bar on top of your client
#for help on how to use or install this snippet, see #mircscripting @ undernet
alias ame { 
  var %i = 1 
  while ($chan(%i)) { 
    if (!$istok(%exclude,$chan(%i),44)) { 
      describe $chan(%i) $1- 
    } 
    inc %i 
  } 
} 
alias addchan { 
  set %exclude $addtok(%exclude,$1,44) 
} 
alias delchan { 
  set %exclude $remtok(%exclude,$1,1,44) 
}
alias noame { $dialog(ame_dialog,ame_dialog) } 
dialog ame_dialog { 
  title "Anti /ame script" 
  size -1 -1 167 69 
  option dbu 
  list 1, 2 13 69 53, sort size vsbar 
  text "Channels currently added:", 3, 2 4 68 8, center 
  button "Exit", 2, 125 53 37 12, ok 
  button "Add", 4, 125 10 37 12 
  text "Add a channel to the current list", 5, 77 8 46 15, center 
  button "Remove", 6, 125 30 37 12 
  text "Remove a channel from the current list", 7, 77 26 46 21, center 
  box "Channels", 8, 74 1 90 48 
} 
on 1:DIALOG:ame_dialog:init:0:{ 
  didtok ame_dialog 1 44 %exclude 
} 
on 1:DIALOG:ame_dialog:sclick:4:{ 
  addchan $?="Insert a channel" 
  did -r ame_dialog 1 
  didtok ame_dialog 1 44 %exclude 
} 
on 1:DIALOG:ame_dialog:sclick:6:{ 
  delchan $did(1).seltext 
  did -r ame_dialog 1 
  didtok ame_dialog 1 44 %exclude 
}

menu menubar {
  Channel Restricted /ame:/noame
}