// https://rathena.org/board/topic/130125-request-for-a-guild-winner-room/

prontera,155,181,5	script	Sample#enter	757,{
	doevent "Sample::OnEnter";
}

prontera,151,175,5	duplicate(Sample#enter)	Sample#enter_1	757
prontera,155,175,5	duplicate(Sample#enter)	Sample#enter_2	757
prontera,159,175,5	duplicate(Sample#enter)	Sample#enter_3	757


-	script	Sample	-1,{
	
	OnInit:
		.map$ = "prt_fild01";
		.castle_map$ = "prtg_cas01";
		end;
		
	OnAgitStart:
	
		// FALLTHROUGH
	OnTimer86400000:
		stopnpctimer;
		.guild_id = 0;
		end;
		
	OnAgitEnd:
		.guild_id = getcastledata(.castle_map$, CD_GUILD_ID);
		if (.guild_id)
			initnpctimer;
		end;
		
	OnEnter:
		if (.guild_id && getcharid(2) == .guild_id)
			warp .map$, 0, 0;
		else 
			npctalk "You need a guild that conquered the Guild Castle.", strnpcinfo(3), bc_self;
		end;
		
	OnHour00:
		.@max = rand(10, 20) - mobcount(.map$, strnpcinfo(3)+"::OnMVPKill");
		for (.@i = 0; .@i < .@max; .@i++)
			monster .map$, 0, 0, "--ja--",(-1 - MOBG_BLOODY_DEAD_BRANCH), 1, strnpcinfo(3)+"::OnMVPKill";
		end;
		
	OnHour03:
	OnHour10:
	OnHour15:
	OnHour22:
		.@max = 10 - mobcount(.map$, strnpcinfo(3)+"::OnTreasureKill");
		for (.@i = 0; .@i < .@max; .@i++)
			monster .map$, 0, 0, "--ja--", 1902, 1, strnpcinfo(3)+"::OnTreasureKill";
		end;
		
	OnMVPKill:
		end;
		
	OnTreasureKill:
		end;
}