##############################
#     Quiets dialog (+q)     #
# by PlasmaStar @ freenode   #
# Plasmastar510@hotmail.com  #
#  use /quiets or top menu   #
##############################

menu menubar {
  Quiets:quiets
}

dialog -l QuietsDialog {
  size -1 -1 212 127
  title "mIRC Channel Quiets"
  option dbu
  list              1, 5   5   202 100, vsbar hsbar extsel
  button "&Edit",   2, 5   110 60  12
  button "&Remove", 3, 70  110 60  12
  button "&Ok",     4, 135 110 60  12,  ok
}

alias quiets {
  if ($status = connected) {
    echo -cn info $chan * Retrieving $chan quiets...
    mode $chan +q
  }
  else {
    echo -acn info * /quiets: not connected to server
  }
}

raw 728:*: {
  haltdef
  if (!$dialog(qDialog)) {
    dialog -m qDialog QuietsDialog
  }
  if (!%RetrievingQuiets) {
    %RetrievingQuiets = $true
    dialog -t qDialog mIRC Channel Quiets - Retrieving...
    did -r qDialog 1
  }
  did -az qDialog 1 $4 ( $+ $5 $+ ) $asctime($6)
}

raw 344:*: {
  ; Quiets on Hybrid (OFTC uses this)
  haltdef
  if (!$dialog(qDialog)) {
    dialog -m qDialog QuietsDialog
  }
  if (!%RetrievingQuiets) {
    %RetrievingQuiets = $true
    dialog -t qDialog mIRC Channel Quiets - Retrieving...
    did -r qDialog 1
  }
  did -az qDialog 1 $3 ( $+ $4 $+ ) $asctime($5)
}

raw 729:*: {
  haltdef
  if ($dialog(qDialog)) {
    dialog -t qDialog mIRC Channel Quiets $2
    if (%RetrievingQuiets) {
      unset %RetrievingQuiets
    }
    else {
      did -r qDialog 1
    }
    did -b qDialog 2
    did -b qDialog 3
  }
  else {
    echo -cn info $2 * No channel quiets
  }
}

raw 345:*: {
  ; Quiets on Hybrid (OFTC uses this)
  haltdef
  if ($dialog(qDialog)) {
    dialog -t qDialog mIRC Channel Quiets $2
    if (%RetrievingQuiets) {
      unset %RetrievingQuiets
    }
    else {
      did -r qDialog 1
    }
    did -b qDialog 2
    did -b qDialog 3
  }
  else {
    echo -cn info $2 * No channel quiets
  }
}

on *:DIALOG:qDialog:*:*: {
  var %chan = $gettok($dialog(qDialog).title, 4, 32)
  if ($devent != mouse) {
    if ($devent == init) {
      did -b qDialog 2
      did -b qDialog 3
    }
    if ($devent == sclick) {
      if ($did == 1) {
        if ($me isop %chan) {
          if ($did(qDialog, 1, 0).sel == 1) {
            did -e qDialog 2
          }
          else {
            did -b qDialog 2
          }
          did -e qDialog 3
        }
        else {
          did -b qDialog 2
          did -b qDialog 3
        }
      }
      if ($did == 3) {
        if (%chan != -) {
          var %line = $did(qDialog, 1, 1).sel
          var %mask
          var %modes
          var %numselect = $did(qDialog, 1, 0).sel
          var %select = 0
          while (%select < %numselect) {
            inc %select
            %mask = $gettok($did(qDialog, 1, %line), 1, 32)
            %modes = $addtok(%modes, %mask, 32)
            did -d qDialog 1 $did(qDialog, 1, 1).sel
            if ($numtok(%modes, 32) == $modespl) {
              mode %chan - $+ $str(q, $numtok(%modes, 32)) %modes
              %modes = $null
            }
          }
          if ($numtok(%modes, 32)) {
            mode %chan - $+ $str(q, $numtok(%modes, 32)) %modes
          }
          did -b qDialog 2
          did -b qDialog 3
        }
      }
    }
    if ($devent == dclick) {
      if ($did == 1) {
        clipboard $did(qDialog, 1).seltext
        echo -acn info * $did(qDialog, 1).seltext copied to clipboard
      }
    }
  }
}