* Copyright © Uwe Zimmermann, [email protected]
*
***** SUB-CIRCUIT
* A is the solar cell area in cm^2
* Is and Isc are expressed as current densities in A/cm^2
* P is the irradiance in W/m^2
* N is the number of cells
*
* CONNECTIONS: POSITIVE PV CONNECTOR
* |
* | NEGATIVE PV CONNECTOR
* | |
.subckt solarcell 1 2
.params N=1 A=1 Rsh=100k Rs=100m Is=1e-12 Eg=1.12 IDF=1 Isc=35m Tci=1e-3 Cjo=30n Vbr=2 P=1000 Tnom=25 T=25
D1 4 3 dsc temp={T}
E1 5 3 1 2 {1/N}
Rshunt 4 3 {Rsh/A}
Rseries 5 4 {Rs/A}
F1 2 1 E1 {A}
IL 3 4 {(Isc*(1+Tci*(T-Tnom)))*P/1000}
.model dsc D(Is={Is/A} Eg={Eg} Tnom=25 Rs=1p N={IDF} Cjo={Cjo/A} M=.5 BV={Vbr/N} Ibv=1u)
.ends
*
* Siemens SM110-24
.subckt SM110-24 1 2
.params Rsh=30k Rs=30 Is=6e-10 Eg=1.12 Isc=3.5/100 Vbr=114 P1=1000 P2=1000 P3=1000 P4=1000 P5=1000 P6=1000
X1 1 3 solarcell N=12 A=100 Rsh={Rsh} Rs={Rs} Is={Is} Eg={Eg} Isc={Isc} Vbr={Vbr} P={P1}
X2 3 4 solarcell N=12 A=100 Rsh={Rsh} Rs={Rs} Is={Is} Eg={Eg} Isc={Isc} Vbr={Vbr} P={P2}
X3 4 5 solarcell N=12 A=100 Rsh={Rsh} Rs={Rs} Is={Is} Eg={Eg} Isc={Isc} Vbr={Vbr} P={P3}
X4 5 6 solarcell N=12 A=100 Rsh={Rsh} Rs={Rs} Is={Is} Eg={Eg} Isc={Isc} Vbr={Vbr} P={P4}
X5 6 7 solarcell N=12 A=100 Rsh={Rsh} Rs={Rs} Is={Is} Eg={Eg} Isc={Isc} Vbr={Vbr} P={P5}
X6 7 2 solarcell N=12 A=100 Rsh={Rsh} Rs={Rs} Is={Is} Eg={Eg} Isc={Isc} Vbr={Vbr} P={P6}
D1 4 1 dbypass
D2 6 4 dbypass
D3 2 6 dbypass
.model dbypass D(IS=157.42E-15 N=.55821 RS=7.1588E-3 IKF=1.0000E3 XTI=2 EG=1.0800 CJO=3.8909E-9 M=.89931 VJ=3.8210 ISR=466.15E-9 NR=4.9950 BV=63.917 IBV=404.13E-6 mfg=Vishay type=Schottky)
.ends
Comments