Pasted

@echo off
rem This is 1.0. In 1.1 I will make the ISO compatibility check actually work regardless of the extension, and
rem use WIT to truly check to make sure it's a valid image for Wii and GC games via a title check.
rem Don't worry about time usage. WIT's ID and title checking is near instantaneous.
 
rem Make sure it's a real ISO
echo Checking file for compatibility...
rem setlocal enableDelayedExpansion
echo %~x1|findstr /ir "^\.iso$ ^\.gcm$ ^\.gcz$ ^\.ciso$ ^\.wbfs$" >nul
rem If no error...
if not errorlevel 1 (
    echo File extension is valid. Attempting to start the game...
) else (
    echo File is not a valid format for Dolphin. Exiting...
    exit /b
)
 
rem Check for Xenoblade Chronicles image, using WIIMM ISO tools
rem This works regardless of the filename
rem But you must have the WIIMM ISO tools installed (extract their zip and run the Windows-install.exe)
wit list -H %1|findstr /ir "^SX4.01.*$" >nul
if not errorlevel 1 (
    echo Detected Xenoblade! Using Dolphin-X instead...
    start "" /d C:\Drake\Games\Wii\Dolphin-X /b C:\Drake\Games\Wii\Dolphin-X\Dolphin-X.exe --batch --exec=%1
    exit /b
)
 
rem Check for The Legend of Zelda: Twilight Princess GC image
wit list -H %1|findstr /ir "^GZ2.01.*$" >nul
if not errorlevel 1 (
    echo Detected Zelda: TP for GC! Using Dolphin-Z instead...
    start "" /d C:\Drake\Games\Wii\Dolphin-Z /b C:\Drake\Games\Wii\Dolphin-Z\Dolphin-Z.exe --batch --exec=%1
    exit /b
)
 
echo Detected standard game. Using normal Dolphin...
start "" /d C:\Drake\Games\Wii\Dolphin /b C:\Drake\Games\Wii\Dolphin\Dolphin64.exe --batch --exec=%1
 
 
REM DOpus Chooser Dialogue:
REM {code|<message>|<option 1>[=<value 1>][+<option 2>[=<value 2>]...]}