Pasted

###############################################
# Relay script 1.0 by ChiefDean
# irc.HeatWaveIRC.net #Heatwave
###############################################
 
Menu * {
  -
  Relay Setup: {
    set %serv1 $input(Enter Server One here.,e,Relay Script 1.0 by ChiefDean)
    set %chan1 $input(Enter Channel One here.,e,Relay Script 1.0 by ChiefDean)
    set %serv2 $input(Enter Server Two here.,e,Relay Script 1.0 by ChiefDean)
    set %chan2 $input(Enter Channel Two here,e,Relay Script 1.0 by ChiefDean)
    if ($numtok(%serv1 %chan1 %serv2 %chan2,32) == 4) { $input(Setup Complete.Remember to turn the power on!,,Script 1.0 by ChiefDean) }
    else { $input(Critical Setup Error! Please return to Relay Setup and Start over!,,Script 1.0 by ChiefDean) }
  }
  $iif($group(#Relay) == On,$style(1)) Relay Power Switch
  .$iif($group(#Relay) == On,$style(2)) On: .enable #Relay
  .$iif($group(#Relay) == Off,$style(2)) Off: .disable #Relay
 
  -
}
alias -l net {
  var %netcount $scon(0)
  while %netcount {
    if ($scon(%netcount).network == $1) { var %netid %netcount }
    dec %netcount
  }
  scon %netid return $!cid
}
alias -l relay { 
  scid $net($1)
  if ($me ison $3) { $2- }
}
alias -l RCheck { 
  if ($1 == $2) && ($3 == $4) { return 1 }
  else return 0
}
#Relay on
on *:TEXT:*:#:{
  if ($rcheck($network,%serv1,$chan,%chan1)) { relay %serv2 msg %chan2 $+(<,$nick,@,$network,>) $1- }
  elseif ($rcheck($network,%serv2,$chan,%chan2)) { relay %serv1 msg %chan1 $+(<,$nick,@,$network,>) $1- }
}
on *:MODE:#:{
  if ($rcheck($network,%serv1,$chan,%chan1)) { relay %serv2 msg %chan2 $nick sets mode $1- }
  elseif ($rcheck($network,%serv2,$chan,%chan2)) { relay %serv1 msg %chan1 $nick sets mode $1- }
}
on *:NICK: {   
  if ($rcheck($network,%serv1)) { relay %serv2 msg %chan2 $nick is now known as $newnick on $network }
  elseif ($rcheck($network,%serv2)) { relay %serv1 msg %chan1 $nick is now known as $newnick on $network }
}
on *:join:#: {  
  if ($rcheck($network,%serv1,$chan,%chan1)) { relay %serv2 msg %chan2 $Nick has joined $chan on $network }
  elseif ($rcheck($network,%serv2,$chan,%chan2)) { relay %serv1 msg %chan1 $Nick has joined $chan on $network }
}  
on *:quit: {  
  if ($rcheck($network,%serv1,$chan,%chan1)) { relay %serv2 msg %chan2 14 $+ $nick has just quit $+($network,.) }
  elseif ($rcheck($network,%serv2,$chan,%chan2)) { relay %serv1 msg %chan1 14 $+ $nick has just quit $+($network,.) }   
} 
on *:kick:#: {  
  if ($rcheck($network,%serv1,$chan,%chan1)) { relay %serv2 msg %chan2 $knick was kicked from $chan by $+($nick,) on $network }
  elseif ($rcheck($network,%serv2,$chan,%chan2)) { relay %serv1 msg %chan1 $knick was kicked from $chan by $+($nick,) on $network }   
} 
on *:part:#: {  
  if ($rcheck($network,%serv1,$chan,%chan1)) { relay %serv2 msg %chan2 $Nick has left $chan on $network }
  elseif ($rcheck($network,%serv2,$chan,%chan2)) { relay %serv1 msg %chan1 $Nick has left $chan on $network }   
} 
on *:ACTION:*:#: {  
  if ($rcheck($network,%serv1,$chan,%chan1)) { relay %serv2 ctcp %chan2 action $nick $1- }
  elseif ($rcheck($network,%serv2,$chan,%chan2)) { relay %serv1 ctcp %chan1 action $nick $1- }
}
 
#Relay End